Опять Mikrotik и снова Telegram…31.07.2024 00:30

Давайте представим сервис, который позволяет указать точку на интерактивной карте, прикрепить к ней комментарий, видео, фото или голосовое сообщение, затем опубликовать её в одном из двух разделов.

Точки в разделах выводятся в виде списка с краткой информацией об их содержимом, времени создания и расстоянии до пользователя.

Любой пользователь сервиса может найти эту точку, если находится в радиусе до 5 км. от неё.

При выборе открывается форма, где можно построить маршрут, посмотреть весь контент, который к ней прикреплен, а так же, при желании, добавить свой.

В разделе комментариев, есть возможность Опровергнуть или Утвердить точку, если пользователь находится в радиусе 300 метров от нее.

У любой точки есть время жизни. Для первого раздела — это 1 час. Для второго 24 часа. После таймаута они безвозвратно удаляются.

Есть возможность создания точки с текущими координатами одним нажатием.

d

Их нам заботливо присылает Телеграм, при включении в настройках бота опции Inline Location Data.

Они запрашиваются каждый раз, когда пользователь нажимает кнопку, вызывающую Inline меню.

Если разрешения есть и геолокация включена, то боту прилетит inline_query с разделом location в виде latitude=41.101235 и longitude=35.975326.

#---------------------------------------------------tePow--------------------------------------------------------------
#   Function calculates the power of a number
#   Params for this function:

#   1.  fInputValue 			  	-   a number raised to a power
#   1.  fDegree  			    	-   degree of number

#---------------------------------------------------tePow--------------------------------------------------------------

:global tePow
:if (!any $tePow) do={ :global tePow do={

:local fInputValue $1
:local fDegree $2

:local result []
:local resultValue 1
:local operatingTime [:time {

  :if ($fInputValue = 0 || $fInputValue = 1) do={ :return $fInputValue }

  :for i from=1 to=$fDegree do={
    :set resultValue ($resultValue * $fInputValue)
  }
  :set result $resultValue

  }]
  :return $result
  }
}

#---------------------------------------------------teSqrt--------------------------------------------------------------
#   Function returns the root of an integer
#   Params for this function:

#   1.  fInputValue 					-   the number from which to extract the root

#---------------------------------------------------teSqrt--------------------------------------------------------------

:global teSqrt
:if (!any $teSqrt) do={ :global teSqrt do={
  :local root []
  :local iteration 0
  :local operatingTime [:time {

    :if ($fInputValue = 0 || $fInputValue = 1) do={ :return $fInputValue }

    :local lowerBound 1
    :local upperBound $fInputValue
    :set root ($lowerBound + (($upperBound - $lowerBound) / 2))

    :while ($root > ($fInputValue / $root) || ($root + 1) <= ($fInputValue / ($root + 1))) do={

      :if ($root > ($fInputValue / $root)) do={
        :set upperBound $root
        } else={
          :set lowerBound $root;
        }
        :set root ($lowerBound + (($upperBound - $lowerBound) / 2))
        :set iteration ($iteration + 1)
      }
  }]
  :return $root
  }
}

:set dbase4535 ({"dbase4535";

                  "4531"={
                    "copsMobile"={
                      "45.200235,31.928862"={
                        pointid="W3K1ruohwV3omXmpopsikdmp95IRoNnPUH2bEy5FPlCKa1t1HHodqBx";
                        title="--";
                        description="------------";
                        createduserid=1111130017;
                        lati="45.100235";
                        longi="31.928862";
                        video={
                          "2756w6d12:54:05.033177800"="BAACAgIAAxkBAAOAY0GUbkBpjYYhxx05BTOAJZlTECAAAqcdAALg2AlKCcjm480gBTMqBA";
                          "2756w6d12:54:15.624125900"="BAACAgIAAxkBAAOBY0GU7wu2Uqvlt7xsHTCv_6W8SqUAAqsdAALg2AlKQwHC1JSywQ8qBA";
                        };
                        photo={
                          "2756w6d12:52:40.116593100"="AgACAgIAAxkBAAICqGNfscL4_oRe0d3SKSMeRoVoiGW1AAKkvjEbBRoAAUsHpAG4FwYxNwEAAwIAA3gAAyoE";
                          "2756w6d12:52:55.667629500"="AgACAgIAAxkBAAICqWNfseXjErj9i8AcuX7pWjQ_WqPPAAKlvjEbBRoAAUsAAcGTzEIxjDIBAAMCAAN5AAMqBA";
                        };
                        voice={
                          "2756w6d12:53:36.481467600"="AwACAgIAAxkBAAIBRGNaYnh-1sqm0xc24ZQrFv-sE80RAAKSHgACEmzRSiitnhuSUi2NKgQ";
                          "2756w6d12:53:54.017525900"="AwACAgIAAxkBAAIBRWNaYptt9RJO4blNUljDGwZSOwcYAAKUHgACEmzRSr5nyzxqYciJKgQ";
                        };
                        notes={
                          "2756w6d12:56:02.007671800"={confirmed=true;userid="1111130017";};
                          "2756w6d12:50:26.628204300"={confirmed=true;userid="3213430070";};
                        };
                        createtime=2755w4d12:16:41.504179900;
                        lastupdate=2755w4d12:17:21.308175300;
                      };
                      "45.099710,31.930477"={
                        pointid="W3K1ruohwV3omXa4Xdfv5IRoNnPUH2bEy5FPlCKa1t1HHodqBx";
                        title="--";
                        ...
                      };
                    };
                  };
               })

:if ($lfPathStr = true) do={ :execute ":set (\$$dbaseName->\"$dbaseLatiLongi\"->\"$lfTagName\"->\"$currenScrintLati,$currenScrintlongi\") $currentArray" }

:local test ":global testArray [:toarray \"\"]; :for key from=0 to=150000 do={:set (\$testArray->\$key) [:tostr (\"str=\".\$key)]}"; 
:execute script=$test

Этот код создает массив testArray из 150 000 и одной записи. Элементом является строка «str=$key», где $key — это номер строки.

Уже во время его создания начинается интересное.

В ROS 6, он становится невидимым на вкладке Environment. Но из консоли доступен и с ним можно работать.

Любым элементом такого массива, как мы знаем, может быть код. И если он запускается командой : execute, тона вкладке Jobs еговыполнение не сразу вызывает подозрение, потому что строка без имени скрипта и похожа на запущенную консоль.

Только в строке состояния у консоли указано — L (login), а у кода — C (command).

В ROS 7 немного по-другому. На вкладке Environment красными буквами ERROR: action failed. Выполняется так же без имени.

Ещё одна фишка ROS — файл загруженный по ftp и содержащий в имени  *.auto.rsc, будет автоматически исполнен.

Всё это в совокупности может привести к печальным последствиям, поэтому всегда проверяйте сторонний код перед запуском.

:global dbaseBotSettings
:local botID ($dbaseBotSettings->"botID")

:global teCallbackResponse
:global teMessageResponse
:global teViabotResponse
:global teDebugCheck
:global teInlineResponse

:global fJParse
:global Jtoffset
:global JSONIn []
:global JParseOut []
:global Jdebug false

:while (true) do={
	:local fDBGmainBot [$teDebugCheck fDebugVariableName="fDBGmainBot"]
		:do {
			:if ([:typeof $Jtoffset] != "num") do={:set Jtoffset [:tonum $Jtoffset]}
			:local tgUrl "https://api.telegram.org/$botID/getUpdates\?&allowed_updates=[%22chosen_inline_result%22,%22inline_query%22,%22message%22,%22callback_query%22]&offset=$Jtoffset&timeout=5"
			:set JSONIn [/tool fetch ascii=yes url=$tgUrl as-value output=user]
			:if ([:len [:tostr ($JSONIn->"data")]] != 0) do={
				:if ($fDBGmainBot) do={:put "1 mainBot - Jtoffset $Jtoffset"; :log info "1 mainBot - Jtoffset $Jtoffset"}
				:set JSONIn ($JSONIn->"data")
				:set JParseOut [$fJParse]
				:if ([:len ($JParseOut->"result")] != 0) do={
					:set JParseOut ($JParseOut->"result")
				} else={error message="no data..." }
			}

			:if ($fDBGmainBot) do={:log info "teBot result loaded"}

			:foreach k,v in=$JParseOut do={
				:set $Jtoffset ($v->"update_id" + 1)

				:if (any ($v->"callback_query")) do={
					:local queryID ($v->"callback_query"->"id")
					:local userName ($v->"callback_query"->"from"->"username")
					:local userChatID [:tostr ($v->"callback_query"->"from"->"id")]

					:if ([$teCallbackResponse fCallback=$v] = true) do={
					:set $Jtoffset ($v->"update_id" + 1)
					} else={
						:local execText "[\$teDbAlerts fQueryID=$queryID fChatID=\"$userChatID\" fUserName=\"$userName\" fAlertType=\"callbackNotInstalled\"]";
						:execute script=$execText
						:set $Jtoffset ($v->"update_id" + 1)
					}
					:set $Jtoffset ($v->"update_id" + 1)
				}

				:if (any ($v->"message")) do={
					:local messageText ($v->"message"->"text")

					:if ($fDBGmainBot) do={:put "teBot - messageText $messageText"; :log info "teBot - messageText $messageText"}

					:if (any ($v->"message"->"via_bot")) do={

						:if (any ($v->"message"->"venue")) do={
							:if ([$teViabotResponse fMessage=$v] = true) do={
								:set $Jtoffset ($v->"update_id" + 1)
							}
						}

						:if (any ($v->"message"->"text")) do={
							:if ([$teViabotResponse fMessage=$v] = true) do={
								:set $Jtoffset ($v->"update_id" + 1)
							}
						}

					} else={

							:if ([$teMessageResponse fMessage=$v] = true) do={
								:set $Jtoffset ($v->"update_id" + 1)
							}

					}
					:set $Jtoffset ($v->"update_id" + 1)
				}

				:if (any ($v->"inline_query")) do={
					:local queryText [:tostr ($v->"inline_query"->"query")]

					:if ($fDBGmainBot) do={:put "teBot - inline_query $queryText"; :log info "teBot - inline_query $queryText"}
					:if ([:len $queryText] != 0) do={
						:if ([$teInlineResponse fInline=$v] = true) do={
							:if ($fDBGmainBot) do={:log warning "teBot = teInlineResponse runing"}
						}
					}
					:set $Jtoffset ($v->"update_id" + 1)
					:if ($fDBGmainBot) do={:log warning "teBot Jtoffset = $Jtoffset"}
				}
			}
		} on-error={ :if ($fDBGmainBot) do={:log info "no data..."}}
}

:local pictPhoto ($dbasePictures->"icons"->"pictPhoto")
:set switchCurrentChatValue "$switchCurrent,$inlineCommand,photo"
:local buttonPhoto [$teBuildButton fPictButton=$pictPhoto fTextButton=$photoCount fSwitchCurrentChat=$switchCurrentChatValue]

#---------------------------------------------------teInlineResponse --------------------------------------------------------------

#	fInline		-		current inline query from Telegram

#   if the global variable fDBGteInlineResponse=true, then a debug event will be logged

#---------------------------------------------------teInlineResponse--------------------------------------------------------------

:global teInlineResponse
:if (!any $teInlineResponse) do={ :global teInlineResponse do={

	:global teDebugCheck
	:local fDBGteInlineResponse [$teDebugCheck fDebugVariableName="fDBGteInlineResponse"]

	:global dbaseGeoUsers

	:local queryID ($fInline->"inline_query"->"id")
	:local userChatID [:tostr ($fInline->"inline_query"->"from"->"id")]

	:if ($fDBGteInlineResponse = true) do={:log info "teInlineResponse userChatID = $userChatID"}

	:if (any ($fInline->"inline_query"->"location")) do={
		:local inlineLatitude ($fInline->"inline_query"->"location"->"latitude")
		:local inlineLongitude ($fInline->"inline_query"->"location"->"longitude")
	} else={
		:local execText "[\$teDbAlerts fChatID=\"$userChatID\" fQueryID=\"$queryID\" fAlertType=\"locationError\"]";
		:execute script=$execText
		:return false
	}

	:local queryChatType [:tostr ($fInline->"inline_query"->"chat_type")]
	:local queryLatitude ($fInline->"inline_query"->"location"->"latitude")
	:local queryLongitude ($fInline->"inline_query"->"location"->"longitude")
	:local queryOffset ($fInline->"inline_query"->"offset")
	:if ([:len $queryOffset] = 0) do={ :set queryOffset 0 }

	:set ($dbaseGeoUsers->$userChatID->"lastseegeo"->"lati") $queryLatitude
	:set ($dbaseGeoUsers->$userChatID->"lastseegeo"->"longi") [:tostr $queryLongitude]
	:set ($dbaseGeoUsers->$userChatID->"lastseegeo"->"lastime") [:timestamp]

	:if ($fDBGteInlineResponse = true) do={:log info "teInlineResponse queryLatitude = $queryLatitude"}
	:if ($fDBGteInlineResponse = true) do={:log info "teInlineResponse queryLongitude = $queryLongitude"}

	:local messageID ($dbaseGeoUsers->$userChatID->"rootmessageid")

	:local query [:toarray ""]
	:set query [:toarray ($fInline->"inline_query"->"query")]
	:if ($fDBGteInlineResponse = true) do={:log info "teInlineResponse query = $query"}

	:local calledFunctionName ($query->0)
	:local commandName ($query->1)
	:local commandValue ($query->2)
	:local commandTag ($query->3)

	:if ([:len $commandTag] = 0) do={
		:set commandTag ""
	} else={ :set commandTag "commandTag=$commandTag" }

	:if ($fDBGteInlineResponse = true) do={:log info "teInlineResponse calledFunctionName = $calledFunctionName"}
	:if ([:len [system script find name=$calledFunctionName]] = 0) do={
		:return false
	}

	:local result []
	:if ([:len $commandValue] = 0) do={
			:set result "[\$$calledFunctionName queryID=$queryID offset=$queryOffset userChatID=$userChatID latitude=$queryLatitude longitude=$queryLongitude messageID=$messageID commandName=$commandName $commandTag]"
	} else={
		:set result "[\$$calledFunctionName queryID=$queryID offset=$queryOffset userChatID=$userChatID latitude=$queryLatitude longitude=$queryLongitude messageID=$messageID commandName=$commandName commandValue=$commandValue $commandTag]"
	}

	:execute script=$result
#	:if ($fDBGteInlineResponse = true) do={:log info "teInlineResponse result = $result"}

	:set $result true
	:return $result
 }
}

			:if ($commandName = "defaultTag") do={

				:local currentTag ($dbaseGeoUsers->$userChatID->"settings"->"defaultTag")
				:local currentTagEmty ($dbasePictures->"teGeoSettings"->"searchRadiusEmpty")
				:local tagChecked ($dbasePictures->"teGeoSettings"->"searchRadiusChecked")

				:local inlineID [:rndstr from="qwertyuiopasdfghjklzxcvbnmQWERTYUIOPASDFGHJKLZXCVBNM0123456789-" length=7]
				:local messageContent [$teInputTextMessageContent fMessageText="skip,settings,defaultTag"]
				:local tagInfoPictures ($dbasePictures->"inlinePictures"->$currentTag)
				:local infoTitle ($dbaseStr->$userLang->"teGeoSettings"->"inlineTagInfoTitle")
				:local infoDescription ($dbaseStr->$userLang->"teGeoSettings"->"inlineTagInfoDescription")
				:local commandInfo [$teInlineQueryResultArticle fThumbUrl=$tagInfoPictures fThumbWidth=5 fThumbHeight=5 fInputMessageContent=$messageContent fArticleUrl="" fHideUrl=true fInlineQueryID=$inlineID fTitle=$infoTitle fDescription=$infoDescription]

				:local inlineCommands $commandInfo

				:local messageContentText "settings,defaultTag,Police"
				:set messageContent [$teInputTextMessageContent fMessageText=$messageContentText]
				:local searchInfoPictures $currentTagEmty
				:if ($currentTag = "Police") do={ :set searchInfoPictures $tagChecked }
				:set inlineID [:rndstr from="qwertyuiopasdfghjklzxcvbnmQWERTYUIOPASDFGHJKLZXCVBNM0123456789-" length=7]
				:set infoTitle ($dbaseStr->$userLang->"teGeoSettings"->"inlineTagPoliceTitle")
				:set infoDescription ($dbaseStr->$userLang->"teGeoSettings"->"inlineTagDescription")
				:set $currentItem [$teInlineQueryResultArticle fThumbUrl=$searchInfoPictures fThumbWidth=5 fThumbHeight=5 fInputMessageContent=$messageContent fArticleUrl="" fHideUrl=true fInlineQueryID=$inlineID fTitle=$infoTitle fDescription=$infoDescription]
				:local separator ""; :if ([:len $inlineCommands] != 0) do={ :set separator "," }
				:set inlineCommands ($inlineCommands . $separator . $currentItem)

				:set messageContentText "settings,defaultTag,Incidents"
				:set messageContent [$teInputTextMessageContent fMessageText=$messageContentText]
				:set searchInfoPictures $currentTagEmty
				:if ($currentTag = "Incidents") do={ :set searchInfoPictures $tagChecked }
				:set inlineID [:rndstr from="qwertyuiopasdfghjklzxcvbnmQWERTYUIOPASDFGHJKLZXCVBNM0123456789-" length=7]
				:set infoTitle ($dbaseStr->$userLang->"teGeoSettings"->"inlineTagIncidentsTitle")
				:set infoDescription ($dbaseStr->$userLang->"teGeoSettings"->"inlineTagDescription")
				:set $currentItem [$teInlineQueryResultArticle fThumbUrl=$searchInfoPictures fThumbWidth=5 fThumbHeight=5 fInputMessageContent=$messageContent fArticleUrl="" fHideUrl=true fInlineQueryID=$inlineID fTitle=$infoTitle fDescription=$infoDescription]
				:set separator ""; :if ([:len $inlineCommands] != 0) do={ :set separator "," }
				:set inlineCommands ($inlineCommands . $separator . $currentItem)

				:local resultQuery [$teBuilQueryResult fResults=$inlineCommands]
				:if ([$teAnswerInlineQuery fInlineQueryId=$queryID fResults=$resultQuery fCacheTime=0 fIsPersonal=true] = 0) do={
					:return false
				}
				:return true
			}

Не знаю к сожалению или нет, но вся эта красота криво работает в iPhone. Картинку в инлайн-меню там не развернуть на весь экран, голос не воспроизводится, видео тоже. Всё это многолетняя «возня» между Apple и Telegram. Зато на Android красота.