Хочешь я посижу в интернете за тебя?

Все что ты делаешь в сети — можно автоматизировать!

Этот материал касается тебя, если ты хотя бы иногда заходишь в интернет с ноутбука или настольного компьютера.

И неважно занят ли ты круглые сутки постингом в соцсети или пару часов в неделю играешь в онлайн-игры. Немного раскинув мозгами, ты сообразишь, как использовать нижеприведенную информацию с выгодой для себя.

Ведь автоматизировать можно: заполнение новостной ленты в сообществе, выкладку товаров на витрину интернет-магазина или статей на сайт, игру на бирже, добычу золота в Warcraft, перевод слов, общение в месседжерах, сбор бонусов за посещение сайтов, работу в веб-почте, поиск информации в интернете, обработку графики, звука, видео и т.д.

iMacros — плагин для Firefox, Chrome и Internet Explorer.

imacros_logo

iMacros позволяет записывать все свои движения в браузере и получать в результате код на языке макрокоманд, который можно редактировать, сохранять и многократно запускать на разных компьютерах.

Как это работает?

Рассмотрим пример записи постинга на стену группы VK:

1. Запускаем iMacros и нажимаем на кнопку Записать. Эта кнопка включает режим записи всех действий пользователя.

record_macro

2. Пишем сообщение на стену.

3. Нажимаем на кнопку Воспроизвести. Каждый раз при нажатии этой кнопки на стене будет появляться сообщение.

vk_auto_posting

4. В разделе ManageРедактировать можно изменять записанный макрорекордером код (значком »« обозначаются комментарии):

' Открываем страницу с группой
TAB T=1
URL GOTO=https://vk.com/public65209345
' Добавляем текст поста на стену
TAG POS=1 TYPE=TEXTAREA ATTR=ID:post_field CONTENT=spam
' Размещаем пост
TAG POS=1 TYPE=BUTTON ATTR=ID:send_post

5. От такого простого кода толку мало. Но это только начало. Совсем скоро ты узнаешь, как сделать из него что-то стоящее.

6. Готовый скрипт можно сохранить и найти в папке iMacros, которая создается в корневом каталоге пользователя при установке плагина. Макросы хранятся в файлах с расширением iim. Их можно посылать по почте и открывать в текстовых редакторах.

macros_in_sublime

Можно написать скрипт для себя в OS X и делиться им с коллегами, которые используют Windows или Linux.

К сожалению, на данный момент iMacros не работает с мобильными браузерами, хотя версия для Firefox Mobile уже третий год в разработке. Поэтому со смартфона макросы можно запускать только с помощью приложений для удаленного контроля за компьютером (Team Viewer, LogMein, Chrome Remote Dekstop и т.п.).

А теперь рассмотрим процесс использования подробнее.

Установка

1. Установить и запустить браузер Mozilla Firefox (все примеры из статьи испробованы в нем).
2. Открыть страницу для установки плагина.
imacros_install
3. Нажать кнопку Добавить в Firefox.
4. Кликнуть на появившуюся иконку iMacros возле строки поиска.
5. Все! Можно записывать макросы!.
imacros_finish_install

Бывают ситуации, когда срочно нужно скопировать базу клиентов с закрытого корпоративного сайта, доступного только в Intranet. Но устанавливать программы на офисные компьютеры можно только с разрешения руководства и оно не поддерживает эту затею. Не стоит отчаиваться и мучить себя ручным трудом! Ведь iMacros работает и в portable-версии Firefox!

Браузер с iMacros можно носить с собой на флешке и на нее же сохранять собранную информацию.

Заполнение форм

Предположим, что нам нужно очень много места на Яндекс.Диске и чтобы его получить, нам надо создать несколько десятков или сотен аккаунтов на Яндексе. Делать это руками очень утомительное занятие, а с макросами легкое и веселое.

Подготовка данных

Откроем Google Drive и создадим новую таблицу. В первый столбец запишем имена, во второй фамилии, в третий логины и в четвертый пароли.

info_for_new_accaunts

Скачаем лист таблицы в формате CSV.

download_as_csv

Сохраним его под именем new_inbpx.csv и положим в папку iMacros.

"Иван","Иванов","someuser235","some_password_235";
"Иван","Иванов","someuser236","some_password_236";
"Иван","Иванов","someuser237","some_password_237";
"Иван","Иванов","someuser238","some_password_238";
"Иван","Иванов","someuser239","some_password_239";
"Иван","Иванов","someuser240","some_password_240";

А вот код, который поочередно перебирает строки этого файла, заносит каждое поле строки в соответствующую форму и ждет 20 секунд для ввода кода из SMS.

' Обрабатываем 5 строк из файла
SET !LOOP 5
' Путь к файлу с данными для пользователей OS X
SET !DATASOURCE "~/iMacros/new_inbox.csv"
TAB T=1
' Идем на страницу создания почтового ящика
URL GOTO=https://passport.yandex.ru/registration/mail?from=mail&origin=home_v14_ru&retpath=https%3A%2F%2Fmail.yandex.ru
' Имя
TAG POS=1 TYPE=INPUT:TEXT FORM=NAME:NoFormName ATTR=ID:firstname CONTENT={{!COL1}}
' Фамилия
TAG POS=1 TYPE=INPUT:TEXT FORM=NAME:NoFormName ATTR=ID:lastname CONTENT={{!COL2}}
' Логин
TAG POS=1 TYPE=INPUT:TEXT FORM=NAME:NoFormName ATTR=ID:login CONTENT={{!COL3}}
' Пароль
SET !ENCRYPTION NO
TAG POS=1 TYPE=INPUT:PASSWORD FORM=NAME:NoFormName ATTR=ID:password CONTENT={{!COL4}}
TAG POS=1 TYPE=INPUT:PASSWORD FORM=NAME:NoFormName ATTR=ID:password_confirm CONTENT={{!COL4}}
TAG POS=1 TYPE=BUTTON FORM=NAME:NoFormName ATTR=ID:nb-5
' Здесь по умолчанию пишем нужный номер телефона
TAG POS=1 TYPE=INPUT:TEXT FORM=NAME:NoFormName ATTR=ID:phone_number CONTENT=79161234567
TAG POS=1 TYPE=BUTTON FORM=NAME:NoFormName ATTR=ID:nb-2
' Отсчитываем время для ввода кода из SMS
WAIT SECONDS=20

Этот скрипт я записала за пару минут с помощью макрорекордера. Что-то подобное можно сделать для других страниц регистрации аккаунтов, досок объявлений и админок сайтов.

Загрузку файлов на сайт тоже можно автоматизировать. Пример:

' Идем на страницу загрузки
TAB T=1
URL GOTO=http://hostingkartinok.com/
' Выбираем файл для загрузки
TAG POS=1 TYPE=INPUT:FILE FORM=ID:standard-form ATTR=NAME:image_1 CONTENT=/Users/irina/Desktop/icon.jpg
' Загружаем
TAG POS=1 TYPE=A ATTR=ID:standard-upload

download_image

Сохранение данных

С помощью iMacros можно сохранять html-код веб-страниц к себе на компьютер.

SET !EXTRACT_TEST_POPUP NO
' Идем на нужную страницу
URL GOTO=https://www.iphones.ru
' Извлекаем все ее содержимое
TAG POS=1 TYPE=HTML ATTR=* EXTRACT=TXT
' Сохраняем в формате html с именем соответствующим текущей дате и времени
SAVEAS TYPE=EXTRACT FOLDER="~/Site-backup" FILE={{!NOW:ddmmyy_hhnnss}}.html

К этому скрипту легко прилаживается CSV файл со списком ссылок (см. предыдущий раздел), позволяющий за пару минут получить копии нескольких десятков интересующих страниц.

Можно сохранять не целые страницы в файлы, а отдельные части. Пример:

' Идем на нужную страницу
TAB T=1
URL GOTO=http://www.iphones.ru
' Извлекаем название главного стики-поста
TAG POS=11 TYPE=SPAN ATTR=* EXTRACT=TXT
' Сохраняем его
SAVEAS TYPE=EXTRACT FOLDER=* FILE=+_{{!NOW:yyyymmdd_hhnnss}}

extract_text

Чтобы скрипт не отображал уведомления с каждым извлеченным текстов, необходимо поставить в начало кода следующую строку:

SET !EXTRACT_TEST_POPUP NO

Слова в тексте страницы можно искать не только по тегам, в которых они располагаются, но и с помощью регулярных выражений. Это отдельная объемная тема. Подробности здесь.

Еще сайты можно сохранять в виде картинок. Обратите внимание, что iMacros делает скриншоты страниц целиком, а не только видимую на экране часть.

Код:

TAB T=1
URL GOTO=https://www.iphones.ru
SCREENSHOT TYPE=Page FOLDER="~/iMacros" FILE="screen.jpg"

Результат:

iphones_ribbon

При приближении обнаруживается вполне неплохое качество:

iphone_screen

Еще плагин умеет загружать файлы с веб-страниц. Пример:

TAB T=1
' Идем на страницу, где лежат файлы для загрузки
URL GOTO=http://demo.imacros.net/Automate/Downloads
' Открываем папку для сохранения файла. По умолчанию это "~/iMacros/Downloads"
ONDOWNLOAD FOLDER=* FILE=* WAIT=YES
' Загружаем файл по первой ссылке с текстом Download
TAG POS=2 TYPE=A ATTR=TXT:*Download*

Искать эти файлы надо в папке »~/iMacros/Downloads».

Мессенджеры

Бывают такие люди, которые не сделают то, о чем их просишь пока им не напомнишь 20 раз. В прямом смысле этого слова. Напишем скрипт, который каждые полчаса будет отправлять сообщение с напоминанием о просьбе в Skype. Перед его запуском необходимо авторизоваться здесь, сделать активным нужного пользователя и указать число повторов.

' Открываем онлайн-версию Skype
URL GOTO=https://web.skype.com/ru/
' Отправляем сообщение
TAG POS=1 TYPE=TEXTAREA FORM=ID:textarea-bindings ATTR=NAME:messageInput CONTENT="Как там дела? Не готово еще?"
TAG POS=1 TYPE=BUTTON ATTR=TXT:Отправить
' Ждем полчаса
WAIT SECONDS=1800

skype_automation

Автоматизировать общение можно во многих мессенджерах: Google Talk, ICQ и др. Сделать это можно с помощью браузерной версии IM Plus, которая доступна здесь.

im_messengers

В веб-приложения и играх использование стандартного режима записи макроса зачастую не работает. В случае неудачи рекомендую экспериментировать с настройками.

record_options

Полезные фишки

Прокси

На некоторых сайтах за излишний кипеж, создаваемый макросами могут забанить по ip. Чтобы этого избежать следует запускать скрипты от имени разных прокси-серверов. Вот такую команду надо поставить в начало кода:

PROXY ADDRESS=192.1.8.1:8080  

Переменные

Иногда макросу для выполнения требуется ввод каких-либо данных от пользователя. Он осуществляется с помощью команды PROMPT:

TAB T=1
PROMPT "Введите адрес сайта:" !VAR1
URL GOTO=https://www.{{!VAR1}}

imacros_prompt

Планирование скриптов

С iMacros можно работать из командной строки. Тонкости этого процесса описаны здесь.

Соответственно, макросы запускаются из исполняемых файлов, которые можно добавлять в Cron (системный планировщик задач). Это процесс отличается для каждой операционной системы и здесь мы его рассматривать не будем.

Отключаем загрузку картинок

Чтобы ускорить выполнение скрипта можно отключить загрузку картинок, поставив в начале кода такую строку:

FILTER TYPE=IMAGES STATUS=O

Где взять больше информации

Люди по всему миру активно осваивают этот инструмент и с радостью делятся своими наработками на Github, где можно найти сотни готовых примеров кода.

А вот ссылки на самые важные разделы официальной документации:

Аналоги

Я не знаю бесплатных аналогов iMacros, которые могли сравниться c ним по количеству функций и легкости освоения (для человека не знающего JavaScript и другие языки программирования). Но iOpus не единственные, кто озадачился вопросом автоматизации действий в браузере.

SEO-шникам и людям, занятым тестированием веб-приложений рекомендую узнать подробнее о следующих программах (возможно, найдете что-то полезное для себя):

Несмотря на то что iMacros не имеет конкурентов по простоте использования и уже 15 лет на рынке, его установили всего лишь 10 миллионов человек из трех миллиардов пользователей интернета. Очень много людей пока не осознали важность автоматизации своего труда.

imacros

P.S. Название предмета статьи наводит на мысль, что Apple приложила руку к созданию плагина. Но это не так.

Создатель iMacros — немецкая компания iOpus. Она была основана 1 июня 2000-го (по данным CrunchBase). Вскоре после этого состоялся выход первой версии плагина.

iTunes заработал только в январе 2001-года, а первый iPod поступил в продажу в октябре того же года. Когда iOpus называли свой продукт, они понятия не имели о магическом влиянии приставки «i» на продажи.

©  iphones.ru